Abhängige DropDowns

Abhängige DropDowns in Formularen

Abhängige Dropdowns gehören zu häufigen Anforderungen in Power Apps.
Diese Dropdowns werden auch oft kaskadierende Dropdowns genannt.

„Abhängig“ bedeutet dabei:
Je nachdem, was wir im ersten Dropdown auswählen, ändert sich automatisch die Auswahlliste im zweiten Dropdown.

Ein klassisches Beispiel:
Wählst du als Hauptkategorie „Hardware“, sollen im zweiten Dropdown nur noch passende Optionen wie „Laptop“ oder „Monitor“ erscheinen anstatt aller verfügbarer Werte.

Ich zeige dir Schritt für Schritt, wie du abhängige Dropdowns in Power Apps inkl. sauberer Datenstruktur umsetzt.

Schritt 1: SharePoint Datenstruktur

Der Startpunkt ist eine saubere Datenstruktur.

Für diesen Anwendungsfall (Tickets inkl. Zuordnung von Kategorie und Subkategorie) ist es sinnvoll, die Kategorie-Auswahlmöglichkeiten in einer separaten SharePoint Liste abzuspeichern. Aus der Ticket Liste greifen wir dann auf die korrekten Kategorie-Kombination zu.

Warum ist das sinnvoll?

• Bessere Wartbarkeit, da Kategorie-Änderungen direkt in SharePoint gepflegt werden können.
• Weniger Fehler, durch Reduzierung von manuellen Eingaben
• Saubere Filterung, in Power Apps

Schritt 2: Bearbeitungsformular in Power Apps

Öffne Power Apps und füge ein Bearbeitungsformular für die Tickets ein.

Schritt 3: Abhängige DropDowns erstellen

Füge dir in der entsprechenden DataCard der Kategorie 2 ComboBoxen ein.

ComboBox 1 = Hauptkategorie (1)

ComboBox 2 = Subkategorie (2)

Schritt 4: Hauptkategorie befüllen

Füge in der ComboBox der Hauptkategorie die Auswahlmöglichkeiten der Spalte hinzu.

DataCardValue_Hauptkategorie
Items = Choices(IT_Tickets_Kategorien.Hauptkategorie)

Schritt 5: Subkategorie befüllen

Die ComboBox der Subkategorie befüllst du jetzt gefiltert basierend auf der Auswahl der Hauptkategorie.

DataCardValue_Subkategorie
Items = 
Filter(
    IT_Tickets_Kategorien;
    Hauptkategorie.Value = DataCardValue_Hauptkategorie.Selected.Value
)

Schritt 6: Werte korrekt speichern

Um die Auswahl korrekt zu speichern, musst du die Update Eigenschaft der DataCard anpassen.

Ticket_Kategorie_DataCard1
Update = 
{
    Id: LookUp(
        IT_Tickets_Kategorien;
        Hauptkategorie.Value = DataCardValue_Hauptkategorie.Selected.Value And
Subkategorie = DataCardValue_Subkategorie.Selected.Subkategorie
    ).ID
}

Schritt 7: Datensätze bearbeiten (DefaultSelectedItems)

Um die korrekten Werte für das Bearbeiten des Datensatzes anzuzeigen, musst du die DefaultSelectedItems der ComboBoxen entsprechend anpassen.

DataCardValue_Hauptkategorie
DefaultSelectedItems = 
If(
    Form_Ticket.Mode = FormMode.New;
    Blank();
    {Value:LookUp(IT_Tickets_Kategorien;ID = ThisItem.Ticket_Kategorie.Id).Hauptkategorie.Value}
)

DataCardValue_Subkategorie
DefaultSelectedItems = 
If(
    Form_Ticket.Mode = FormMode.New;
    Blank();
    LookUp(
        IT_Tickets_Kategorien;
        ID = ThisItem.Ticket_Kategorie.Id
    )
)

Hier findest du weiterführende Details zu DefaultSelectedItems

Bonus: Ungültige Kombinationen verhindern

Wenn die Hauptkategorie geändert wird, kann die gewählte Subkategorie ungültig werden. Daher solltest du zusätzlich eine Prüfung hinterlegen, um Fehleingaben zu verhindern. 

DataCardValue_Subkategorie
DefaultSelectedItems = 
If(
    Form_Ticket.Mode = FormMode.New Or Not(
        LookUp(
            IT_Tickets_Kategorien;
            ID = ThisItem.Ticket_Kategorie.Id
        ).Subkategorie in ShowColumns(
            Filter(
                IT_Tickets_Kategorien;
                Hauptkategorie.Value = DataCardValue_Hauptkategorie.Selected.Value
            );
            Subkategorie
        )
    );
    Blank();
    LookUp(
        IT_Tickets_Kategorien;
        ID = ThisItem.Ticket_Kategorie.Id
    )
)

Ich hoffe, diese Tipps helfen dir dabei, deine Apps übersichtlich und benutzerfreundlich zu gestalten.

Melde dich gerne für meinen Newsletter an, in dem ich dir Tipps und Tricks rund um Power Apps & Power Automate zusende.

 Hier geht's zum Detailvideo: