DefaultSelectedItems

ComboBox Defaults richtig setzen!

Formulare und Eingabemöglichkeiten sind ein zentraler Bestandteil vieler Power Apps. Doch je mehr Felder Nutzer:innen manuell ausfüllen müssen, desto höher ist die Fehlerquote – und desto schlechter die Nutzererfahrung.
Eine einfache, aber extrem wirkungsvolle Optimierung: ComboBoxen mit sinnvollen Standardwerten vorausfüllen.

Ich zeige dir Schritt für Schritt, wie du ComboBoxen in Power Apps korrekt vorausfüllst für:

• Auswahlspalten
• Personenspalten
• Nachschlagespalten

jeweils für Single Select und Multi Select.

Schritt 1: SharePoint Listen erstellen

In diesem Beispiel arbeite ich mit zwei SharePoint Listen.

Die Hauptliste: Lagerbewegungen

Mit den Spalten Buchungsart, Verantwortliche_Person, Artikel und Artikel_2

Die Unterliste: Lagerartikel

Mit den Spalten Artikelnummer und Lagerplatz

Schritt 2: Bearbeitungsformular mit ComboBox in Power Apps

Die erstellten Listen bindest du in Power Apps ein und erstellst ein entsprechendes Bearbeitungsformular. Auswahlfelder werden automatisch als ComboBoxen (Kombinationsfelder) integriert.

Wichtig ist, dass das Formular zum Anlegen (NewForm), zum Bearbeiten (EditForm) und zum Anzeigen (ViewForm) verwendet werden kann.

Den Standardwert (per DefaultSelectedItems) möchten wir nur beim Anlegen eines neuen Datensatzes befüllen. In allen anderen Fällen soll der Wert des zu bearbeitenden oder anzuzeigenden Datensatzes aus der Datenquelle kommen.

Damit dies korrekt funktioniert, musst du eine If-Bedingung hinzufügen, die den Mode des Formulars prüft:

DataCardValue
DefaultSelectedItems= 
If(
    Form_Lagerbewegung.Mode=FormMode.New;
    STANDARDWERT;
    Parent.Default
)

Schritt 3: Default in Auswahlspalten (Choices)

Bei Auswahlspalten ist die Items-Eigenschaft in der Regel:

DataCardValue
Items = Choices([@Lagerbewegungen].Buchungsart)

Diese Funktion liefert eine einspaltige Tabelle mit der Spalte Value zurück:

Einen Default Wert (Datensatz) für Single Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = If(
    Form_Lagerbewegung.Mode=FormMode.New;
    LookUp(Choices(Lagerbewegungen.Buchungsart);Value="Wareneingang");
    Parent.Default
)

Einen Default Wert (Tabelle) für Multi Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung_neu.Mode=FormMode.New;
    Filter(Choices(Lagerbewegungen.Buchungsart);Value="Wareneingang" Or Value="Umlagerung");
    Parent.Default
)

Default in Personenspalte

Personen musst du in Power Apps mithilfe eines vollständigen Personendatensatzes übergeben.
Dafür ist ein korrektes Schema erforderlich, das zumindest die Claims Informationen beinhaltet.

Claims Prefix = 
"i:0#.f|membership|" 

Default Wert für Single Select:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung.Mode=FormMode.New;
    {
        Claims:"i:0#.f|membership|" & User().Email;
        Email:User().Email
    };
    Parent.Default
)

Default Wert für Multi Select:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung_neu.Mode=FormMode.New;
    Table(
        {Claims:"i:0#.f|membership|" & User().Email;Email:User().Email};
        {Claims:"i:0#.f|membership|" & "MAILADRESSE";Email:"MAILADRESSE"}
    );
    Parent.Default
)

Default in Nachschlagespalten - über Choices

In der Haupttabelle werden Nachschlagespalten mit Id und Value in den Choices hinterlegt. In vielen Szenarien reicht das aus, um einen Default Wert zu hinterlegen.

Einen Default Wert (Datensatz) für Single Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung.Mode=FormMode.New;
    LookUp(Choices([@Lagerbewegungen].Artikel);Id=1);
    Parent.Default
)

Einen Default Wert (Tabelle) für Multi Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung_neu.Mode=FormMode.New;
    Table(LookUp(Choices([@Lagerbewegungen].Artikel);Id=1));
    Parent.Default
)

Default in Nachschlagespalten - über Untertabelle

In einigen Szenarien reicht es nicht aus, nur Id und Value für den Default Wert in der App zur Verfügung zu haben.
Dann ist es sinnvoll, die gesamte Untertabelle einzubinden, um auf sämtliche Spalten zugreifen zu können.

DataCardValue
Items = Lagerartikel

Achtung: Sobald du die Items Eigenschaft veränderst und auf die Untertabelle direkt zugreifst, musst du von der DataCard auch die Update Eigenschaft anpassen, um den korrekten Wert in der Haupttabelle abzuspeichern.

Einen Default Wert (Datensatz) für Single Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung.Mode=FormMode.New;
    LookUp(Lagerartikel;Lagerplatz="R1-Fach01");
    Parent.Default
)

DataCard
Update = 
{Id:DataCardValue_Artikel.Selected.ID;Value:DataCardValue_Artikel.Selected.Artikelnummer}

Einen Default Wert (Tabelle) für Multi Select kannst du so hinterlegen:

DataCardValue
DefaultSelectedItems = 
If(
    Form_Lagerbewegung_neu.Mode=FormMode.New;
    Filter(Lagerartikel;Lagerplatz="R1-Fach01");
    Parent.Default
)

DataCard
Update = 
ForAll(
    DataCardValue_Artikel_neu.SelectedItems;
    {Id:ThisRecord.ID;Value:ThisRecord.Artikelnummer}
)

Hier gehts zu meinen 5 Tipps für besser designte Bearbeitungsformulare in Power Apps

5 Tipps für besser designte Bearbeitungsformulare in Power Apps

Ich hoffe, diese Anleitung hilft dir dabei, deine Formulare in Power Apps benutzerfreundlich und ansprechend zu gestalten.

Melde dich gerne für meinen Newsletter an, in dem ich dir Tipps und Tricks rund um Power Apps & Power Automate zusende.

 Hier geht's zum Detailvideo: