Datumsfilter

Der ultimative Guide für Datumsfilter in Power Apps

In vielen Power Apps ist das Filtern nach Datum eine zentrale Funktion. Typische Beispiele sind Zeiterfassungen, Terminübersichten oder Aufgabenlisten. Doch sobald neben dem Datum auch Uhrzeiten oder ganze Monatsbereiche berücksichtigt werden sollen, wird es schnell etwas komplexer.

Ich zeige dir Schritt für Schritt, wie du in Power Apps:

• nach einem konkreten Datum
• nach einem Datumsbereich
• nach Datum inklusive Uhrzeit
• sowie nach kompletten Monaten

filtern kannst.

Zusätzlich zeige ich dir dynamische Dropdowns für Stunden, Minuten, Monate und Jahre, die automatisch aktualisiert werden.

SharePoint Liste

Die Grundlage für die App bildet eine SharePoint Liste.

Für dieses Beispiel habe ich eine Tabelle mit

• Datumsspalte ohne Uhrzeit
• Startzeit Spalte mit Datum und Uhrzeit
• Textspalte mit einem Projekt

Galerie nach Datum filtern

Um nach einem bestimmten Datum zu filtern, fügst du dir einen Date Picker (Datumsauswahl) ein. Der ausgewählte Wert kann über die Eigenschaft .SelectedDate ausgelesen werden.

Table1
Items = 
Filter(
    Zeiterfassung;
    Datum = DatePickerCanvas1.SelectedDate
)

Nach einem Datumsbereich filtern

In vielen Anwendungsfällen möchten wir es ermöglichen, nach einem Datumsbereich zu filtern. Füge dir dazu einen zweiten Date Picker ein, um das Enddatum einzutragen.

Um nach dem Datumsbereich zu filtern, musst du die Filterfunktion entsprechend erweitern:

Table1
Items = 
Filter(
    Zeiterfassung;
    Datum >= DatePickerStart.SelectedDate And
    Datum <=DatePickerEnde.SelectedDate
)

Nach Datum inklusive Uhrzeit filtern

In manchen Szenarien enthält eine Spalte nicht nur ein Datum, sondern auch eine Uhrzeit – zum Beispiel bei einer Startzeit.

Ein Date Picker liefert jedoch standardmäßig immer:

Datum + 00:00 Uhr

Um Datensätze nach Datum inkl. Uhrzeit zu filtern, musst du die Zeiteingabe (Stunden, Minuten) per Dropdown ermöglichen und den Filter entsprechend anpassen.

DropdownStunden
Items = Sequence(24;0;1)

Das erzeugt eine Tabelle mit den Werten (Value): 0 bis 23

DropdownMinuten
Items = Sequence(4;0;15)

Das erzeugt eine Tabelle mit den Werten (Value): 0, 15, 30, 45

Jetzt musst du das ausgewählte Datum und die Uhrzeit mit der DateAdd Funktion kombinieren und den Filter entsprechend anpassen:

Table1
Items =
Filter(
    Zeiterfassung;
    Startzeit = DateAdd(
        DatePickerCanvas1.SelectedDate;
        DropdownStunden.Selected.Value * 60 + DropdownMinuten.Selected.Value;
        TimeUnit.Minutes
    )
)

Nach kompletten Monaten filtern

Eine sehr häufige Anforderung ist das Filtern nach einem bestimmten Monat, zum Beispiel alle Einträge im Februar 2026.

Füge dir zwei Dropdowns ein, um die Monats- und Jahresauswahl zu ermöglichen.

DropdownMonat
Items = 
AddColumns(
    Sequence(12);
    Monat;
    Text(Date(2026;Value;1);"mmmm")
)

Das erzeugt eine Tabelle mit 2 Spalten. Eine Value Spalte mit den Werten 1 bis 12. Zusätzlich eine Spalte Monat mit dem korrespondierendem Monatsnamen. Damit ermöglichst du die Eingabe des Monats über den Monatsnamen, kannst im Hintergrund aber mit dem Zahlenwert arbeiten.

DropdownJahr
Items = 
Sequence(
    Year(Today()) - 2024 + 1;
    2024
)

Das erzeugt eine dynamische Auswahlmöglichkeit ausgehend von 2024 bis zum aktuellen Jahr.

Um die Datumsfilterung für den ausgewählten Monat und das Jahr zu ermöglichen, ist folgender Filter notwendig:

Table1
Items =
Filter(
    Zeiterfassung;
    Datum >= Date(
        DropdownCanvas_Jahr.Selected.Value;
        DropdownCanvas_Monat.Selected.Value;
        1
    ) And Datum < DateAdd(
        Date(
            DropdownCanvas_Jahr.Selected.Value;
            DropdownCanvas_Monat.Selected.Value;
            1
        );
        1;
        TimeUnit.Months
    )
)

Ich hoffe, diese Anleitung hilft dir dabei, deine Apps übersichtlicher und nutzerfreundlicher zu gestalten.

Melde dich gerne für meinen Newsletter an, in dem ich dir Tipps und Tricks rund um Power Apps & Power Automate zusende.

 Hier geht's zum Detailvideo: